# Copyright 2014 The Chromium Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//mojo/public/mojo_application.gni")
import("//mojo/public/tools/bindings/mojom.gni")

group("apptest") {
  testonly = true

  deps = [
    ":apptests",
    ":service",
  ]
}

mojo_native_application("service") {
  output_name = "example_service"

  sources = [
    "example_service_application.cc",
    "example_service_application.h",
    "example_service_impl.cc",
    "example_service_impl.h",
  ]

  deps = [
    ":bindings",
    "//mojo/public/cpp/application:standalone",
    "//mojo/public/cpp/bindings",
    "//mojo/public/cpp/system",
    "//mojo/public/cpp/utility",
  ]
}

mojo_native_application("apptests") {
  output_name = "example_apptests"

  testonly = true

  sources = [
    "example_apptest.cc",
  ]

  deps = [
    ":bindings",
    "//mojo/public/cpp/application:standalone",
    "//mojo/public/cpp/application:test_support_standalone",
    "//mojo/public/cpp/bindings:callback",
    "//mojo/public/cpp/environment",
    "//mojo/public/cpp/system",
  ]

  data_deps = [ ":service" ]
}

mojom("bindings") {
  sources = [
    "example_service.mojom",
  ]
}