mojo/services/window_manager/BUILD.gn

# Copyright 2014 The Chromium Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/config/ui.gni")
import("//mojo/public/mojo_application.gni")

mojo_native_application("window_manager") {
  sources = [ "main.cc" ]

  public_deps = [
    ":lib",
  ]

  deps = [
    "//base",
    "//mojo/application",
    "//mojo/public/c/system:for_shared_library",
    "//mojo/services/public/cpp/view_manager",
  ]
}

source_set("lib") {
  sources = [
    "basic_focus_rules.cc",
    "basic_focus_rules.h",
    "focus_controller.cc",
    "focus_controller.h",
    "focus_controller_observer.h",
    "focus_rules.h",
    "native_viewport_event_dispatcher_impl.cc",
    "native_viewport_event_dispatcher_impl.h",
    "window_manager_app.cc",
    "window_manager_app.h",
    "window_manager_delegate.h",
    "window_manager_impl.cc",
    "window_manager_impl.h",
    "view_event_dispatcher.cc",
    "view_event_dispatcher.h",
    "view_target.cc",
    "view_target.h",
    "view_targeter.cc",
    "view_targeter.h",
  ]

  deps = [
    "//base",
    "//ui/base",
    "//ui/gfx",
    "//ui/gfx/geometry",
    "//mojo/application",
    "//mojo/common",
    "//mojo/converters/input_events",
    "//mojo/services/public/cpp/view_manager",
    "//mojo/public/interfaces/application:application",
    "//mojo/services/public/interfaces/native_viewport",
    "//mojo/services/public/interfaces/window_manager",
  ]
}

test("window_manager_unittests") {
  sources = [
    "view_target_unittest.cc",
    "view_targeter_unittest.cc",
    "window_manager_api_unittest.cc",
    "window_manager_test_util.cc",
    "window_manager_test_util.h",
    "window_manager_unittests.cc",
  ]

  public_deps = [
    ":lib",
  ]

  deps = [
    "//base/test:test_support",
    "//mojo/application_manager",
    "//mojo/edk/system",
    "//mojo/environment:chromium",
    "//mojo/services/public/cpp/view_manager",
    "//mojo/services/public/interfaces/view_manager",
    "//mojo/services/public/interfaces/window_manager",
    "//mojo/shell:test_support",
    "//testing/gtest",
    "//ui/events:test_support",
    "//ui/gfx",
    "//ui/gfx:test_support",
    "//ui/gl",
  ]

  if (use_x11) {
    deps += [ "//ui/gfx/x" ]
  }
}