services/authentication/BUILD.gn

# Copyright 2015 The Chromium Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//mojo/public/tools/bindings/mojom.gni")

if (is_android) {
  import("//build/config/android/rules.gni")

  android_library("authentication") {
    java_files = [
      "src/org/chromium/mojo/authentication/AuthenticationApplicationDelegate.java",
      "src/org/chromium/mojo/authentication/AuthenticationServiceImpl.java",
      "src/org/chromium/mojo/authentication/NetworkServiceProxyFactory.java",
    ]

    deps = [
      ":interfaces_java",
      "//mojo/public/interfaces/application:application_java",
      "//mojo/public/java:application",
      "//mojo/public/java:bindings",
      "//mojo/public/java:system",
      "//mojo/services/authenticating_url_loader_interceptor/interfaces:interfaces_java",
      "//mojo/services/authentication/interfaces:interfaces_java",
      "//mojo/services/network/public/interfaces:interfaces_java",
      "//services/intent_receiver:bindings_java",
      "//third_party/android_tools:google_play_services_default_java",
    ]
  }

  mojom("interfaces") {
    sources = [
      "authentication_impl_db.mojom",
    ]
  }
} else {
  import("//mojo/public/mojo_application.gni")

  mojo_native_application("authentication") {
    sources = [
      "dummy_authentication_app.cc",
    ]

    deps = [
      "//mojo/common",
      "//mojo/public/cpp/application",
      "//mojo/public/cpp/application:standalone",
      "//mojo/public/cpp/bindings",
      "//mojo/public/cpp/system",
      "//mojo/services/authentication/interfaces",
    ]
  }
}